/usr/ld Not enough room for program headers

[horseriver]

On Wed, Jan 09, 2013 at 01:28:12PM +0800, Peter Teoh wrote:
> On Sun, Jan 6, 2013 at 11:17 AM, horseriver <horserivers at gmail.com> wrote:
> 
> > On Fri, Jan 04, 2013 at 11:34:24AM +0400, Игорь Пашев wrote:
> > > 2013/1/4 horseriver <horserivers at gmail.com>
> > > >
> > > > Not enough room for program headers
> > >
> > >
> >
> >
> > > Try to search the Web for this. E. g.:
> > > http://lists.gnu.org/archive/html/bug-gnu-utils/2002-08/msg00176.html
> >
> > thanks!
> >
> > in my compile option. I have specifiedmy ld-script file ,and there is no
> > SIZEOF_HEADER in that file ,
> >
> >
> can u show us your ld script?   according to the msg00176.html above, it is
> possible to arise because u have place your other section wrongly (eg,
> .text), and nothing to do with SIZEOF_HEADER.

OK! I copy this ld-script here 

VSYSCALL_BASE = 0xffffe000;

SECTIONS
{
  . = VSYSCALL_BASE ;

  .hash           : { *(.hash) }		:text
  .dynsym         : { *(.dynsym) }
  .dynstr         : { *(.dynstr) }
  .gnu.version    : { *(.gnu.version) }
  .gnu.version_d  : { *(.gnu.version_d) }
  .gnu.version_r  : { *(.gnu.version_r) }

  /* This linker script is used both with -r and with -shared.
     For the layouts to match, we need to skip more than enough
     space for the dynamic symbol table et al.  If this amount
     is insufficient, ld -shared will barf.  Just increase it here.  */
  . = VSYSCALL_BASE + 0x400;

  .text           : { *(.text) }		:text =0x90909090

  .eh_frame_hdr   : { *(.eh_frame_hdr) }	:text :eh_frame_hdr
  .eh_frame       : { KEEP (*(.eh_frame)) }	:text
  .dynamic        : { *(.dynamic) }	  	:text :dynamic
  .useless        : {
  		  *(.got.plt) *(.got)
		  *(.data .data.* .gnu.linkonce.d.*)
		  *(.dynbss)
		  *(.bss .bss.* .gnu.linkonce.b.*)
  }							:text
}

/*
 * We must supply the ELF program headers explicitly to get just one
 * PT_LOAD segment, and set the flags explicitly to make segments read-only.
 */
PHDRS
{
  text PT_LOAD FILEHDR PHDRS FLAGS(5); /* PF_R|PF_X */
  dynamic PT_DYNAMIC FLAGS(4); /* PF_R */
  eh_frame_hdr 0x6474e550; /* PT_GNU_EH_FRAME, but ld doesn't match the name */
}

/*
 * This controls what symbols we export from the DSO.
 */
VERSION
{
  LINUX_2.5 {
    global:
	__kernel_vsyscall;
    	__kernel_sigreturn;
    	__kernel_rt_sigreturn;

    local: *;
  };
}

/* The ELF entry point can be used to set the AT_SYSINFO value.  */
ENTRY(__kernel_vsyscall);

I can not find what is wrong ,are there some advice ?

thanks~

> 
> 
> > but where this error come from ?
> >
> >
> >
> >
> > _______________________________________________
> > Kernelnewbies mailing list
> > Kernelnewbies at kernelnewbies.org
> > http://lists.kernelnewbies.org/mailman/listinfo/kernelnewbies
> >
> 
> 
> 
> -- 
> Regards,
> Peter Teoh